ข้อใดเป็นผลลัพธ์จากการใช้ฟังก์ชัน if c2 10 ผ่าน ไม่ผ่าน

ฟังก์ชัน IF เป็นหนึ่งในฟังก์ชันที่ง่ายและมีประโยชน์ที่สุดในสมุดงาน Excel ทำการทดสอบทางตรรกะอย่างง่ายซึ่งขึ้นอยู่กับผลการเปรียบเทียบและจะส่งกลับค่าหนึ่งค่าหากผลลัพธ์เป็น TRUE หรือค่าอื่นหากผลลัพธ์เป็น FALSE

• ตัวอย่างที่ 1: การใช้ฟังก์ชัน IF อย่างง่ายสำหรับตัวเลข
• ตัวอย่างที่ 2: การใช้ฟังก์ชัน IF สำหรับค่าข้อความ
• ตัวอย่างที่ 3: การใช้ฟังก์ชัน IF สำหรับค่าวันที่
• ตัวอย่างที่ 4: การใช้ฟังก์ชัน IF กับฟังก์ชัน AND, OR ร่วมกัน
• ตัวอย่างที่ 5: การใช้ฟังก์ชัน IF ที่ซ้อนกัน

 ไวยากรณ์:

ไวยากรณ์สำหรับฟังก์ชัน IF ใน Excel คือ:

=IF (logical_test, [value_if_true], [value_if_false])

 ข้อโต้แย้ง:

• logical_test: จำเป็น เป็นเงื่อนไขที่คุณต้องการทดสอบ
• value_if_true: ไม่จำเป็น. ค่าเฉพาะที่คุณต้องการส่งคืนหากผลลัพธ์ logical_test เป็น TRUE
• value_if_false: ไม่จำเป็น. ค่าที่คุณต้องการส่งคืนหากผลลัพธ์ logical_test เป็น FALSE

หมายเหตุ:

1 ถ้า ค่า_if_จริง ถูกละไว้:

• ถ้า ค่า_if_จริง อาร์กิวเมนต์ถูกละไว้ในฟังก์ชัน IF เช่นเฉพาะเครื่องหมายจุลภาคตามหลัง logical_test มันจะส่งคืนศูนย์เมื่อตรงตามเงื่อนไข ตัวอย่างเช่น: =IF(C2>100,, "Low ").
• หากคุณต้องการใช้เซลล์ว่างแทนศูนย์หากตรงตามเงื่อนไขคุณควรใส่เครื่องหมายคำพูดคู่ "" ลงในพารามิเตอร์ที่สองดังนี้: =IF(C2>100, "", "Low").

2 ถ้า ค่า_if_false ถูกละไว้:

• ถ้า ค่า_if_false พารามิเตอร์ถูกละไว้ในฟังก์ชัน IF จะส่งกลับค่า FALSE เมื่อไม่ตรงตามเงื่อนไขที่ระบุ เช่น: =IF(C2>100, "High").
• หากคุณใส่เครื่องหมายจุลภาคหลังอาร์กิวเมนต์ value_if_true มันจะส่งคืนศูนย์เมื่อไม่ตรงตามเงื่อนไขที่ระบุ เช่น: =IF(C2>100, "High" ,).
• หากคุณป้อนเครื่องหมายคำพูดคู่ "" ลงในพารามิเตอร์ที่สามเซลล์ว่างจะส่งกลับหากไม่ตรงตามเงื่อนไข เช่น: =IF(C2>100, "High" , "").

 เดินทางกลับ:

ทดสอบเงื่อนไขเฉพาะส่งคืนค่าที่สอดคล้องกันที่คุณระบุสำหรับ TRUE หรือ FALSE

 ตัวอย่าง:

ตัวอย่างที่ 1: การใช้ฟังก์ชัน IF อย่างง่ายสำหรับตัวเลข

ตัวอย่างเช่นสมมติว่าคุณต้องการทดสอบรายการค่าหากค่ามากกว่าค่าที่ระบุ 100 ข้อความ "ดี" จะปรากฏขึ้นหากไม่แสดงข้อความ "ไม่ดี" จะถูกส่งกลับ

ป้อนสูตรด้านล่างและคุณจะได้ผลลัพธ์ด้านล่างตามที่คุณต้องการ

=IF(B2>100,"Good","Bad")

ตัวอย่างที่ 2: การใช้ฟังก์ชัน IF สำหรับค่าข้อความ

กรณีที่ 1: ฟังก์ชัน IF สำหรับค่าข้อความที่ไม่คำนึงถึงตัวพิมพ์เล็กและใหญ่:

ที่นี่ฉันมีตารางที่มีรายการงานและสถานะการเสร็จสิ้นตอนนี้ฉันต้องการทราบว่างานใดที่ต้องดำเนินการและไม่จำเป็นต้องทำ เมื่อข้อความในคอลัมน์ C เสร็จสมบูรณ์ "ไม่ใช่" จะปรากฏขึ้นมิฉะนั้น "ใช่" จะถูกส่งกลับ

โปรดใช้สูตรต่อไปนี้ตอนนี้เซลล์จะส่งคืน "ไม่ใช่" เมื่อข้อความในคอลัมน์ C แสดงเป็น "เสร็จสมบูรณ์" ไม่ว่าจะเป็นตัวพิมพ์ใหญ่หรือตัวพิมพ์เล็ก หากข้อความอื่นในคอลัมน์ C "ใช่" จะถูกส่งกลับ ดูภาพหน้าจอ:

=IF(C2="completed", "No", "Yes")

กรณีที่ 2: ฟังก์ชัน IF สำหรับค่าข้อความที่คำนึงถึงตัวพิมพ์เล็กและใหญ่:

ในการทดสอบค่าข้อความโดยคำนึงถึงตัวพิมพ์เล็กและตัวพิมพ์ใหญ่คุณควรรวมฟังก์ชัน IF เข้ากับฟังก์ชัน EXACT โปรดใช้สูตรด้านล่างจากนั้นระบบจะจดจำเฉพาะข้อความที่มีข้อมูลตรงกันเท่านั้นและคุณจะได้ผลลัพธ์ด้านล่างตามที่คุณต้องการ:

=IF(EXACT(C2,"COMPLETED"), "No", "Yes")

กรณีที่ 3: ฟังก์ชัน IF สำหรับค่าข้อความที่ตรงกันบางส่วน:

บางครั้งคุณต้องตรวจสอบค่าของเซลล์ตามข้อความบางส่วนในกรณีนี้คุณควรใช้ฟังก์ชัน IF, ISNUMBER และ SEARCH ร่วมกัน

ตัวอย่างเช่นหากคุณต้องการตรวจสอบเซลล์ที่มีข้อความ "comp" แล้วส่งคืนค่าที่เกี่ยวข้องโปรดใช้สูตรด้านล่าง และคุณจะได้ผลลัพธ์ตามภาพด้านล่างที่แสดง:

=IF(ISNUMBER(SEARCH("comp",C2)), "No", "Yes")

หมายเหตุ:

• 1. ฟังก์ชัน SEARCH ใช้กับข้อความที่ไม่คำนึงถึงตัวพิมพ์เล็กและใหญ่หากคุณต้องการตรวจสอบข้อความด้วยตัวพิมพ์เล็กและใหญ่คุณควรแทนที่ฟังก์ชัน SEARCH ด้วยฟังก์ชัน FIND แบบนี้:=IF(ISNUMBER(FIND("comp",C2)), "No", "Yes")
• 2. ค่าข้อความเป็นพารามิเตอร์ในสูตร IF คุณต้องใส่ไว้ใน "เครื่องหมายคำพูดคู่"

ตัวอย่างที่ 3: การใช้ฟังก์ชัน IF สำหรับค่าวันที่

กรณีที่ 1: ฟังก์ชัน IF สำหรับวันที่เพื่อเปรียบเทียบวันที่กับวันที่ที่ระบุ:

หากคุณต้องการเปรียบเทียบวันที่เพื่อตรวจสอบว่าวันที่นั้นมากกว่าหรือน้อยกว่าวันที่ที่ระบุฟังก์ชัน IF ก็ช่วยคุณได้เช่นกัน เนื่องจากฟังก์ชัน IF ไม่สามารถจดจำรูปแบบวันที่ได้คุณจึงควรรวมฟังก์ชัน DATEVALUE เข้าด้วยกัน

โปรดใช้สูตรนี้เมื่อวันที่มากกว่า 4/15/2019 จะมีการส่งคืน "ใช่" มิฉะนั้นสูตรจะแสดงข้อความ "ไม่" ดูภาพหน้าจอ:

=IF(D4>DATEVALUE("4/15/2019"), "Yes", "No")

หมายเหตุ: ในสูตรข้างต้นคุณสามารถใช้การอ้างอิงเซลล์ได้โดยตรงโดยไม่ต้องใช้ฟังก์ชัน DATEVALUE เช่นกัน แบบนี้: =IF(D4>$D$1, "Yes", "No").

กรณีที่ 2: ฟังก์ชัน IF สำหรับวันที่ตรวจสอบวันที่มากกว่าหรือน้อยกว่า 30 วัน:

หากคุณต้องการระบุวันที่ที่มากกว่าหรือน้อยกว่า 30 วันนับจากวันที่ปัจจุบันคุณสามารถรวมฟังก์ชัน TODAY เข้ากับฟังก์ชัน IF

โปรดป้อนสูตรนี้:

ระบุวันที่เก่ากว่า 30 วัน: =IF(TODAY()-C4>30,"Older date","")

ระบุวันที่มากกว่า 30 วัน: =IF(C4-TODAY()>30, "Future date", "")

หมายเหตุ หากคุณต้องการใส่ผลลัพธ์ทั้งสองลงในคอลัมน์เดียวคุณต้องใช้ฟังก์ชัน IF ที่ซ้อนกันดังนี้:

=IF(C4-TODAY()>30, "Future date", IF(TODAY()-C4>30, "Older date", ""))

ตัวอย่างที่ 4: การใช้ฟังก์ชัน IF กับฟังก์ชัน AND, OR ร่วมกัน

เป็นการใช้งานทั่วไปที่เราจะรวมฟังก์ชัน IF, AND, OR เข้าด้วยกันใน Excel

กรณีที่ 1: การใช้ฟังก์ชัน IF กับฟังก์ชัน AND เพื่อตรวจสอบว่าเงื่อนไขทั้งหมดเป็นจริงหรือไม่:

ฉันต้องการตรวจสอบว่าตรงตามเงื่อนไขทั้งหมดหรือไม่เช่น: B4 คือสีแดง, C4 มีขนาดเล็กและ D4> 200 หากเงื่อนไขทั้งหมดเป็น TURE ให้ทำเครื่องหมายผลลัพธ์เป็น“ ใช่” หากเงื่อนไขข้อใดข้อหนึ่งเป็น FALSE ให้ส่งกลับ“ ไม่ใช่”

โปรดใช้สูตรนี้และคุณจะได้ผลลัพธ์ตามภาพหน้าจอต่อไปนี้:

=IF(AND(B4="Red",C4="Small", D4>200),"Yes","No")

กรณีที่ 2: การใช้ฟังก์ชัน IF ร่วมกับฟังก์ชัน OR เพื่อตรวจสอบเงื่อนไขข้อใดข้อหนึ่งเป็นจริง:

คุณยังสามารถใช้ฟังก์ชัน IF และ OR เพื่อตรวจสอบว่าเงื่อนไขข้อใดข้อหนึ่งเป็นจริงหรือไม่เช่นฉันต้องการระบุว่าเซลล์ในคอลัมน์ B มีข้อความ "สีน้ำเงิน" หรือ "สีแดง" หากมีข้อความในคอลัมน์ B ใช่จะปรากฏขึ้นมิฉะนั้นจะไม่มีการส่งคืน

ที่นี่คุณควรใช้สูตรนี้และผลลัพธ์ด้านล่างจะแสดง:

=IF(OR(B4="Red",B4="Blue"),"Yes","No")

กรณีที่ 3: การใช้ฟังก์ชัน IF กับฟังก์ชัน AND และ OR ร่วมกัน:

ตัวอย่างนี้ฉันจะรวมฟังก์ชัน IF เข้ากับฟังก์ชัน AND & OR พร้อมกัน สมมติว่าคุณควรตรวจสอบเงื่อนไขต่อไปนี้:

• Condition 1: Column B = “Red” and Column D > 300;
• Condition 2: Column B = “Blue” and Column D > 300.

หากตรงตามเงื่อนไขข้อใดข้อหนึ่งข้างต้นการจับคู่จะถูกส่งกลับมิฉะนั้นไม่

โปรดใช้สูตรนี้และคุณจะได้ผลลัพธ์ด้านล่างตามที่คุณต้องการ:

=IF(AND(OR(B4="Red",B4= "Blue"), D4>300), "Match", "No")

ตัวอย่างที่ 5: การใช้ฟังก์ชัน IF ที่ซ้อนกัน

ฟังก์ชัน IF ใช้เพื่อทดสอบเงื่อนไขและส่งคืนค่าหนึ่งหากตรงตามเงื่อนไขและค่าอื่นหากไม่ตรงตามเงื่อนไข แต่บางครั้งคุณควรตรวจสอบเงื่อนไขมากกว่าหนึ่งเงื่อนไขในเวลาเดียวกันและส่งคืนค่าที่แตกต่างกันคุณสามารถใช้ Nested IF เพื่อแก้ปัญหานี้ได้

คำสั่ง IF ที่ซ้อนกันซึ่งรวมเงื่อนไข IF หลายเงื่อนไขหมายถึงการใส่คำสั่ง IF ไว้ในคำสั่ง IF อื่นและทำกระบวนการนั้นซ้ำหลาย ๆ ครั้ง

ไวยากรณ์สำหรับฟังก์ชัน IF ที่ซ้อนกันใน Excel คือ:

=IF (condition1, result1, IF (condition2, result2, IF (condition3, result3,…)))

หมายเหตุ: ใน Excel 2007 และเวอร์ชันที่ใหม่กว่าคุณสามารถซ้อนฟังก์ชัน IF ได้มากถึง 64 ฟังก์ชันในสูตรเดียวและใน Excel 2003 และเวอร์ชันก่อนหน้าสามารถใช้ฟังก์ชัน IF ที่ซ้อนกันได้เพียง 7 ฟังก์ชันเท่านั้น

กรณีที่ 1: ฟังก์ชัน IF ที่ซ้อนกันเพื่อตรวจสอบหลายเงื่อนไข:

การใช้ฟังก์ชัน Nested IF แบบคลาสสิกคือการกำหนดเกรดตัวอักษรสำหรับนักเรียนแต่ละคนตามคะแนนของตน ตัวอย่างเช่นคุณมีตารางที่มีนักเรียนและคะแนนสอบของพวกเขาตอนนี้คุณต้องการจัดประเภทคะแนนด้วยเงื่อนไขต่อไปนี้:

โปรดใช้สูตรนี้และคุณจะได้ผลลัพธ์ด้านล่างหากคะแนนมากกว่าหรือเท่ากับ 90 คะแนนจะเป็น "ดีเยี่ยม" หากคะแนนมากกว่าหรือเท่ากับ 80 คะแนนจะเป็น "ดี" หากคะแนน มากกว่าหรือเท่ากับ 60 เกรดคือ "ปานกลาง" มิฉะนั้นเกรดจะ "แย่"

=IF(C2>=90, "Excellent", IF(C2>=80, "Good", IF(C2>=60, "Medium", "Poor")))

คำอธิบายของสูตรข้างต้น:

IF(check if C2>=90, if true - returns "Excellent", or else IF(check if C2>=80, if true - returns "Good", or else IF(check if C2>=60, if true - returns "Medium", if false - returns "Poor")))

กรณีที่ 2: ฟังก์ชัน IF ที่ซ้อนกันสำหรับคำนวณราคาตามปริมาณ:

นอกจากนี้ยังสามารถใช้ฟังก์ชัน Nested IF เพื่อคำนวณราคาสินค้าตามปริมาณ

ตัวอย่างเช่นคุณต้องการให้ลูกค้าแบ่งราคาตามปริมาณจำนวนมากขึ้นที่พวกเขาซื้อส่วนลดมากขึ้นที่พวกเขาจะได้รับดังภาพด้านล่างที่แสดง

เนื่องจากราคารวมเท่ากับปริมาณจะคูณราคาดังนั้นคุณควรคูณปริมาณที่ระบุด้วยค่าที่ส่งคืนโดย Ifs ที่ซ้อนกัน โปรดใช้สูตรนี้:

=D2*IF(D2>=101,16, IF(D2>=50, 21, IF(D2>=25, 26, IF( D2>=11, 30, IF(D2>=1, 39, "")))))

หมายเหตุ: คุณยังสามารถใช้การอ้างอิงเซลล์เพื่อแทนที่ตัวเลขราคาคงที่เมื่อข้อมูลต้นทางเปลี่ยนคุณไม่จำเป็นต้องอัปเดตสูตรโปรดใช้สูตรนี้: =D2*IF(D2>=101, B6, IF(D2>=50, B5, IF(D2>=25, B4, IF( D2>=11, B3, IF(D2>=1, B2, "")))))

เคล็ดลับ: การใช้ฟังก์ชัน IF เพื่อสร้างการทดสอบคุณสามารถใช้ตัวดำเนินการเชิงตรรกะต่อไปนี้:

เครื่องมือเพิ่มประสิทธิภาพการทำงานในสำนักงานที่ดีที่สุด

Kutools สำหรับ Excel - ช่วยให้คุณโดดเด่นจากฝูงชน

คุณต้องการทำงานประจำวันให้เสร็จอย่างรวดเร็วและสมบูรณ์แบบหรือไม่? Kutools for Excel นำเสนอคุณสมบัติขั้นสูงที่มีประสิทธิภาพ 300 รายการ (รวมสมุดงานผลรวมตามสีแยกเนื้อหาเซลล์แปลงวันที่และอื่น ๆ ... ) และประหยัดเวลา 80% สำหรับคุณ

• ออกแบบมาสำหรับสถานการณ์การทำงาน 1500 รูปแบบช่วยให้คุณแก้ปัญหา Excel ได้ 80%
• ลดการคลิกแป้นพิมพ์และเมาส์หลายพันครั้งต่อวันช่วยบรรเทาอาการเมื่อยล้าของดวงตาและมือ
• เป็นผู้เชี่ยวชาญด้าน Excel ใน 3 นาที ไม่จำเป็นต้องจำสูตรและรหัส VBA ที่เจ็บปวดอีกต่อไป
• ทดลองใช้ฟรี 30 วันไม่ จำกัด รับประกันคืนเงิน 60 วัน อัปเกรดและสนับสนุนฟรี 2 ปี

แท็บ Office - เปิดใช้งานการอ่านแบบแท็บและการแก้ไขใน Microsoft Office (รวม Excel)

• หนึ่งวินาทีเพื่อสลับไปมาระหว่างเอกสารที่เปิดอยู่มากมาย!
• ลดการคลิกเมาส์หลายร้อยครั้งสำหรับคุณทุกวันบอกลามือเมาส์
• เพิ่มผลผลิตของคุณ 50% เมื่อดูและแก้ไขเอกสารหลายชุด
• นำแท็บที่มีประสิทธิภาพมาสู่ Office (รวมถึง Excel) เช่นเดียวกับ Chrome, Firefox และ Internet Explorer ใหม่